;Set an option so that we can always find the window, regardless of the file name in use.
AutoItSetOption ("WinTitleMatchMode", 2)

;Get a handle to the main window.
Local $hWndMain = WinGetHandle(" - Inkscape", "");

;If we can't find the main window, bail out.
If @error Then
	Exit
	
;The main window is found, continue
Else
	;Focus the main window in case it isn't.
	WinActivate($hWndMain)
	
	;"Save a Copy" keyboard shortcut.
	Send("{SHIFTDOWN}{CTRLDOWN}{ALTDOWN}s")
	Send("{SHIFTUP}{CTRLUP}{ALTUP}")
	
	;Wait for the save window to show up.
	Local $hWndSave = WinWait("[CLASS:#32770]")
	
	;Focus the save window in case it isn't.
	WinActivate($hWndSave)
	
	;Click on the "Save as Type" selection box.
	ControlClick($hWndSave, "","[CLASS:ComboBox; INSTANCE:3]")
	
	;Select the xaml option in the selection box, and press Enter.
	ControlCommand($hWndSave, "", "[CLASS:ComboBox; INSTANCE:3]", "SelectString", "Microsoft XAML (*.xaml)")
	Send("{ENTER}")
	
	;Shortcut key for "Save".
	Send("{ALTDOWN}s")
	Send("{ALTUP}")
	
	;A popup box will appear which asks if you want the output to be compatible with Silverlight. 
	;You have to tick the box manually once, without using this script. After that, the setting is remembered.
	Local $hWndSilverlight = WinWait("XAML Output", "")
	WinActivate($hWndSilverlight)
	
	;Shortcut key for "OK" on the Silverlight message box.
	Send("{ALTDOWN}o")
	Send("{ALTUP}")
	
	;If the file already exists, overwrite the it by pressing Enter.
	Local $hWndOverwrite = WinGetHandle("");
	If @error Then
		Exit
	Else
		WinActivate($hWndOverwrite)
		Send("{ENTER}")
	EndIf
EndIf